a. Summe der x höchsten Werte ermitteln:
=KGRÖSSTE(A1:A100;1)+KGRÖSSTE(A1:A100;2)+KGRÖSSTE(A1:A100;3)
oder: {=SUMME(KGRÖSSTE(A1:A100;{1;2;3}))}
oder: {=SUMME(KGRÖSSTE(A1:A100;ZEILE(INDIREKT("1:10"))))}
Formel ohne geschweifte Klammern eingeben, dann die geschweiften Klammern mit STRG+SHIFT+ENTER erzeugen.
b. Kleinste Abweichung zu 0:
{=INDEX(A1:A100;VERGLEICH(MIN(WENN(A1:A100<>"";ABS(A1:A100)));ABS(A1:A100);0))}
Formel ohne geschweifte Klammern eingeben, dann die geschweiften Klammern mit STRG+SHIFT+ENTER erzeugen.
c. Drittgrößten Wert ermitteln:
=KGRÖSSTE(A1:A100;3)
d. Wert aus letzter gefüllter Zelle:
=VERWEIS(2;1/(A1:A100<>"");A1:A100)
e. Nächstmöglichen Wert ermitteln:
Aus einer Spalte (A1:A100) den nächstmöglichen Wert zum Suchwert (in B1) ermitteln:
{=INDEX(A:A;VERGLEICH(MIN(WENN(A1:A100<>"";ABS(A1:A100-B1)));ABS(A1:A100-B1);0))}
Formel ohne geschweifte Klammern eingeben, dann die geschweiften Klammern mit STRG+SHIFT+ENTER erzeugen.
f. Höchster Wert ohne Vorzeichenbeachtung:
{=MAX(ABS(A1:C100))}
Formel ohne geschweifte Klammern eingeben, dann die geschweiften Klammern mit STRG+SHIFT+ENTER erzeugen.
g. Mittelwert der 10 höchsten Werte ermitteln:
{=MITTELWERT((WENN(A1:A100>=KGRÖSSTE($A1:$A100;10);A1:A100;"")))}
Formel ohne geschweifte Klammern eingeben, dann die geschweiften Klammern mit STRG+SHIFT+ENTER erzeugen.
h. Kleinsten Wert ohne Null ermitteln:
{=MIN(WENN(A1:A100<>0;A1:A100;""))}
Formel ohne geschweifte Klammern eingeben, dann die geschweiften Klammern mit STRG+SHIFT+ENTER erzeugen.
i. Mittelwerte ohne 0 (wenn Werte immer >0) ermitteln:
=SUMME(AA16:AA30)/ZÄHLENWENN(AA16:AA30;">0")
j. Mittelwert der letzten 10 Zeilen ermitteln:
=MITTELWERT(BEREICH.VERSCHIEBEN(A1;ANZAHL(A:A)-10;;10))